[SCRIPT] Remove key after 3x uses

[Spelos]

I created a simple code snipped that hopefully resolves your problem.
Feel free to use the general UnlockDoor function for any of your keys and doors, for it will unlock them just fine without any modifications.

Bare in mind the snipped is controlled by the variables on top.
Feel free to replace variables with string entries if you feel like it.

PHP Code: (Select All)

// Conrol variables for this code snippet
string yourFirstDoor = "myDoor01";
string yourSecondDoor = "myDoor02";
string yourThirdDoor = "myDoor03";

string yourSpecialKey = "myKeyItem";

void OnStart()
{
    // Preloading Resources
    PreloadSound("unlock_door.snt");

    // Callbacks setup
    AddUseItemCallback("", yourSpecialKey, yourFirstDoor, "UnlockDoor", true);
    AddUseItemCallback("", yourSpecialKey, yourSecondDoor, "UnlockDoor", true);
    AddUseItemCallback("", yourSpecialKey, yourThirdDoor, "UnlockDoor", true);
}

// GENERAL DOOR UNLOCK FUNCTION
void UnlockDoor(string &in asItem, string &in asEntity)
{
    SetSwingDoorLocked(asEntity, false, true);
    PlaySoundAtEntity("", "unlock_door.snt", asEntity, 1.0f, false);
    
    // If it's your special key and all doors are unlocked, remove it from the Inventory
    if(asItem == yourSpecialKey && AllDoorsUnlocked())
    {
        RemoveItem(asItem);
    }
    // If it's some other normal key, just remove it without any condition
    else if(asItem != yourSpecialKey)
    {
        RemoveItem(asItem);
        return;
    }
}

// CHECKING IF ALL DOORS ARE UNLOCKED
bool AllDoorsUnlocked()
{
    if(GetSwingDoorLocked(yourFirstDoor) == false && 
       GetSwingDoorLocked(yourSecondDoor) == false && 
       GetSwingDoorLocked(yourThirdDoor) == false)
    {
        return true;
    }
    return false;
}